３軸迷路ロボット
ホーム | パーツ | 工作例 | ロボット制御
ピンポン玉を拾いながら進む迷路脱出ロボット

◆３軸ミュウロボ基本セット工作例
ピンポン玉を運ぶ迷路ロボットを作ってみました。
迷路の壁を感知するため横壁センサーと前壁センサーを取り付けてあります。ピンポン玉を拾うアームにも位置センサーが取り付けてありプログラムは３個のセンサーによって動きをコントロールしています。
横壁センサーで壁に沿って進み前の壁を感知したらアームを振り下ろしピンポン玉を拾いあげます。

<使用パーツ>
●MYU-507 ３軸ミュウロボ基本セット 4,200円(税込)
●リミットスイッチ 158円(税込)

★動画（735KB）はこちら

<壁センサー>

//ピンポン玉を拾いながら進む迷路脱出ロボット(MYU BASIC)
Byte A
A=0
Buzzer 10
Do
	IfLo(1) Then		//前方が壁なら
		後退 1
		停止 10
		Buzzer 5
		If A=0 Then
			Do While In(3)	//In3が押されるまでアームを振り下ろす
				停止 0
				モーター左 0
			Loop
			停止 10
			モーター右 15
			TURN
			A=1
		Else
			TURN
			モーター右 8
			停止 10
			モーター左 8
			停止 10
			A=0
		EndIf
		Do While IN(2)	//横壁まで
			停止 0
			左回り 0
		Loop
	EndIf
	IfLo(2) Then		//横壁なら
		左前 0
	Else
		右前 0
	EndIf
Loop
Proc TURN()	//向きを変える
	停止 10
	後退 2
	停止 10
	右回り 8
	左前 2
	停止 10
	後退 5
	停止 10
EndProc
//迷路脱出ロボット(ドリトル)
ロボ太＝MYU！作る。
ロボ太：転送命令＝「！はじめロボット
　　　　CLA　　//レジスタクリア
　　　　10　ブザー
10　アンカー
　　　　50　1　入力なしジャンプ　//前方が壁ではない
　　　　1　後退
　　　　10　停止
　　　　5　ブザー
　　　　1　CMP　　　　　//レジスタと1と比較
　　　　30　JZ　　　　//1なら
20　アンカー
　　　　0　停止
　　　　0　モーター左
　　　　20　3　入力なしジャンプ
　　　　10　停止
　　　　15　モーター右
　　　　10　ブロック実行
　　　　1　A
　　　　40　ジャンプ
30　アンカー
　　　　10　ブロック実行
　　　　10　モーター右
　　　　10　停止
　　　　10　モーター左
　　　　10　停止
　　　　CLA
40　アンカー
　　　　0　停止
　　　　0　左回り
　　　　40　2　入力なしジャンプ
50　アンカー
　　　　60　2　入力なしジャンプ
　　　　0　左前
　　　　10　ジャンプ
60　アンカー
　　　　0　右前
　　　　10　ジャンプ
10　ブロックはじめ　　　　//TURN
　　　　10　停止
　　　　2　後退
　　　　10　停止
　　　　9　右回り
　　　　2　左前
　　　　10　停止
　　　　5　後退
　　　　10　停止
ブロックおわり
おわりロボット」。
ロボ太！　”com1"ひらけごま。
ロボ太！転送命令。
ロボ太！とじろごま。
 		//迷路脱出ロボット(myurobo.exe)
　　　　CLA　　//レジスタクリア
　　　　ブザー,10
アンカー,10
　　　　入力なしジャンプ,50,1　//前方が壁ではない
　　　　後退,1
　　　　停止,10
　　　　ブザー,5
　　　　CMP,1　　　　　//レジスタと1と比較
　　　　JZ,30　　　　//1なら
アンカー,20
　　　　停止,0
　　　　モーター左,0
　　　　入力なしジャンプ,20,3
　　　　停止,10
　　　　モーター右,15
　　　　ブロック実行,10
　　　　A,1
　　　　ジャンプ,40
アンカー,30
　　　　ブロック実行,10
　　　　モーター右,10
　　　　停止,10
　　　　モーター左,10
　　　　停止,10
　　　　CLA
アンカー,40
　　　　停止,0
　　　　左回り,0
　　　　入力なしジャンプ,40,2
アンカー,50
　　　　入力なしジャンプ,60,2
　　　　左前,0
　　　　ジャンプ,10
アンカー,60
　　　　右前,0
　　　　ジャンプ,10
ブロックはじめ,10　　　　//TURN
　　　　停止,10
　　　　後退,2
　　　　停止,10
　　　　右回り,9
　　　　左前,2
　　　　停止,10
　　　　後退,5
　　　　停止,10
ブロックおわり